* reverse engineering the mdv write routine
    * by Gert van der Knokke
    * based on the initial work of Richard Zidlicky
    * on entry A3 points to $18020 Microdrive control/status and IPC status register
    * D1 is the number of bytes to transmit (fixed ?)
    * A1 points to the first byte of the byte(s) to be transmitted

    L051E4 MOVEQ   #$0E,D0   * common mdv write routine
           MOVE.B  D0,(A3)    * set MDSELECT, MDSELECT_CLK and MD_WRITE
           MOVE.B  D0,(A3)    * and again (why?)
           MOVEQ   #$01,D6    * preset bit number 1 in D6
           LEA     $0002(A3),A2 * setup A2 to $18022 MD transmit register
           MOVEQ   #$09,D5    * set up counter for 10 bytes

    L051F2 MOVEQ   #$00,D4    * setup D4 to all '0'

    L051F4 BSR.S   L0521A    * send 10 of these
           SUBQ.B  #1,D5    * decrement counter
           BGE.S   L051F4    * if greater or equal to zero
           
           MOVEQ   #-$01,D4  * setup D4 to all '1'
           BSR.S   L0521A     * send this
           BSR.S   L0521A    * and again
           
           MOVE.W  #$0F0F,D3 * setup checksum?
           MOVEQ   #$00,D4    * clear D4

    L05206 MOVE.B  (A1)+,D4    * get databyte from A1 in D4 and  increment A1
           ADD.W   D4,D3    * add databyte to checksum in D3
           BSR.S   L0521A    * and send it
           DBF     D1,L05206 * decrement byte counter and repeat if not done
           
           MOVE.W  D3,D4     * copy D3 into D4
           BSR.S   L0521A    * and send lower 8 bits
           LSR.W   #8,D4    * move upper 8 bits to lower 8 bits
           BSR.S   L0521A    * and send these also
           JMP     (A4)    * return ?

    L0521A BTST    D6,(A3)   * test XMIT buffer full bit
           BNE.S   L0521A    * wait if so
           MOVE.B  D4,(A2)    * send byte to transmit data register
           RTS       * done