OldComp.cz • Zobrazit téma - Celoobrazovkový scroll na 48K

Vyhledat témata bez odpovědí | Zobrazit aktivní témata

Obsah fóra » ZX Spectrum, Sinclair a kompatibilní » ZX Spectrum - programování a vývoj software

Všechny časy jsou v UTC + 1 hodina [ Letní čas ]

Celoobrazovkový scroll na 48K

Moderátoři: Jiiira, SCjoe

Stránka 1 z 4

[ Příspěvků: 49 ]

Přejít na stránku 1, 2, 3, 4 Další

Verze pro tisk

Předchozí téma | Následující téma

Autor

Zpráva

pavero

Předmět příspěvku: Celoobrazovkový scroll na 48K

Napsal: 03.08.2013, 14:02

Kecálek

Registrován: 18.05.2013, 11:46
Příspěvky: 183
Bydliště: Ústí nad Orlicí
Has thanked: 11 times
Been thanked: 63 times

Otázka do pranice, je možné dosáhnout plynulého (bez trhání a probliků) celoobrazovkového scrollu na Spectru 48K?

Na ukázku jsem připravil následující kód, jedná se o celoobrazovkový scroll směrem doleva po atributech. Vykreslování probíhá po jednotlivých mikrořádcích od shora, po přesunu osmi mikrořádků se posunou i související atributy. Při vhodném načasování jsem dosáhl plynulosti u prvních dvou třetin obrazovky, zhruba na 17. atributu se již ale obraz "láme".

rambo16.sna (posun dvou třetin obrazovky)
rambo24.sna (posun celé obrazovky)

Uvítám i jákekoliv rady na optimalizaci kódu ;-)

Kód:

      org 29000
START2      ld hl,40000      ;hodnota hl muze byt 30000 nebo 40000
      ld de,16384
      ld bc,6912
      ldir

      im 1
      ei

      ld a,32         ;pocet opakovani
START      push af

      halt         ;pockani na zahajeni vykreslovani obrazu
      ld a, 3
      call WAIT      ;cekani na posun paprsku
            
      call MOVELEFT      ;posun obrazu o 1 atribut doleva
                
      pop af
      dec a
      jr nz,START
      jr START2


MOVELEFT   ld a,24         ;pocet atributu k posunu 1-24
      ld hl,16385
      ld de,16384

mlALL      push af

;pixely                     
      ld a,8
mlPIXEL      push hl
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi       
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi       
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi       
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      pop hl
      ld b,a
      call DOWNHL
      ld a,b
      ld d,h         ;novou hodnotu uloz do DE
      ld e,l       
      dec de
      dec a
      jr nz,mlPIXEL
   

;atributy         
      
      push hl
      push de
      call UPHL
      call ATTRADR

mlATTR      
      ld d,h         ;novou hodnotu uloz do DE
      ld e,l       
      dec de      

      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi       
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi       
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi       
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      dec hl
      ld (hl),0       ;mazaci atribut      
            
      pop de
      pop hl

      pop af
      dec a
      jp nz,mlALL

      ret

;spomalovaci smycka
WAIT      ld b,255
WAIT_INNER   djnz WAIT_INNER
      dec a
      jr nz,WAIT
         ret   

   
;posun ukazatele o jeden bod dolu, registr HL        
DOWNHL    inc h 
   ld a,h
   and 7
   ret nz
   ld a,l
   add a,32
   ld l,a
   ld a,h 
   jr c,DOWNHL2 
   sub 8
   ld h,a
DOWNHL2 cp 88
   ret c
   ld h,64
   ret

;posun ukazatele o jeden bod nahoru, registr HL
UPHL    ld a,h    
   dec h
   and 7
   ret nz
   ld a,l
   sub 32
   ld l,a
   ld a,h 
   jr c,UPHL2 
   add a,8
   ld h,a
UPHL2    cp 64
   ret nc
   ld h,87
   ret      

;vypocet adresy atributu, registr HL
ATTRADR   ld a,h             ;posunuti zacatku
   sub 64             ;obrazovky do nuly
   rrca
   rrca             ; rotace doprava (deleni osmi)
   rrca
   and 3             ;v A je nyni cislo tretiny
   add a,88          ;posun na zacatek atributu
   ld h,a             ;spodni byte (L) je stejny (nemeni se)
   ret

Přílohy:

rambo24.sna [48.03 KiB]
208 krát

rambo16.sna [48.03 KiB]
201 krát

_________________
https://zx-spectrum.cz
https://maps.speccy.cz
https://www.zx-spectrum.cz/collection/
https://cs.speccy.cz
https://spectrumcomputing.co.uk/

Nahoru

dex

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 03.08.2013, 21:19

Pan Štábní

Registrován: 12.05.2013, 22:24
Příspěvky: 1524
Bydliště: u Prahy
Has thanked: 44 times
Been thanked: 386 times

Technicky možno není, nestihne se.
Vždy je nutno vymyslet nějaký trik.
(např. ne posun obecných grafických dat, ale fiillování vzorkem, uloženým v dvoujregistrech, pomocí nastavení SP do VRAM a PUSH - Busyho dema, posun jen každého druhého mikrořádku - tuším Hypnautic World, plocha menší než celá obrazovka, ...).

Nahoru

_dworkin

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 03.08.2013, 22:07

Pan Štábní

Registrován: 23.06.2013, 23:49
Příspěvky: 1119
Has thanked: 100 times
Been thanked: 161 times

Kód:

;pixely                     
      ld a,8
mlPIXEL:
      push hl
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi       
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi       
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi       
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      pop hl
      ld b,a
      call DOWNHL
      ld a,b
      ld d,h         ;novou hodnotu uloz do DE
      ld e,l       
      dec de
      dec a
      jr nz,mlPIXEL

Proc pouzivate obecne fce jako DOWNHL, kdyz jde o rychlost?

Kód:

                    
SCROLL_VLEVO:
      ld a,24+3             ; 3 jsou atributy
      ld   hl,$4001
      ld   de,$4000
mikroradek_cele_tretiny:
      ldi   ; 16 taktu:2byty (de++) = (hl++), ignore bc--
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi   ; 8x

      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi   ; 16x
      
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi   ; 24x

      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi   ; 31x


      inc l
      inc e     ; preskoc posledni sloupec
      
      jr  nz , mikroradek_cele_tretiny
      inc d
;      inc h uz bylo zvednuto v ldi
      dec a
      jr nz, mikroradek_cele_tretiny
      ret

PS: Ale neber me vazne, programuji teprve chvilku.
PSS: Pridal jsem i atributy, kdyz staci jen zvednout o 3 reg. "a".

_________________
Z80 Forth compiler (ZX Spectrum 48kb): https://codeberg.org/DW0RKiN/M4_FORTH

Nahoru

pavero

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 03.08.2013, 22:36

Kecálek

Registrován: 18.05.2013, 11:46
Příspěvky: 183
Bydliště: Ústí nad Orlicí
Has thanked: 11 times
Been thanked: 63 times

_dworkin: jj, obdobný způsob jsem měl naprogramován jako první, je určitě nejrychlejší, jen to má jeden háček, při něm se to trhá jako prase

. Problém je v tom, že není synchronizován posun pixelů a atributů, atributy se posouvají podstatně později a rovněž u pixelů dochází nejprve k posunu každého osmého mikrořádku ve třetině, což také způsobuje trhaný efekt. Viz příloha, kterou lze porovnat s původní rambo24.sna.

Přílohy:

rambo24_2.sna [48.03 KiB]
210 krát

_________________
https://zx-spectrum.cz
https://maps.speccy.cz
https://www.zx-spectrum.cz/collection/
https://cs.speccy.cz
https://spectrumcomputing.co.uk/

Nahoru

pavero

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 03.08.2013, 22:38

Kecálek

Registrován: 18.05.2013, 11:46
Příspěvky: 183
Bydliště: Ústí nad Orlicí
Has thanked: 11 times
Been thanked: 63 times

misticjoe píše:

A je to technicky možné na 128k? Vím, že Pavero to chce mít především pro 48k, jen se ptám.

128K používá dvě VRAMky, mezi kterými lze rychle přepínat, takže tam to takový problém není

_________________
https://zx-spectrum.cz
https://maps.speccy.cz
https://www.zx-spectrum.cz/collection/
https://cs.speccy.cz
https://spectrumcomputing.co.uk/

Nahoru

Busy

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 07.08.2013, 07:03

Óm Nejvyšší

Registrován: 22.05.2013, 21:14
Příspěvky: 3674
Bydliště: Bratislava
Has thanked: 373 times
Been thanked: 798 times

misticjoe píše:

A je to technicky možné na 128k? Vím, že Pavero to chce mít především pro 48k, jen se ptám.

Dve prepinatelne videoramky odbremenia od nutnosti riesenia konfliktu s vycitavanim videoramky a zobrazovacim lucom na monitore, ale samotny scroll procesoru nijak neulahcia. Takze realny poctivy scroll celej obrazovky pomocou LDI:LDI:LDI... sa nestiha ani na 128k.

Btw. jedno LDI trva 16 taktov, takze posun celej obrazovky aj s atributami + nejaka rezia okolo by si vyziadali vyse 110000 taktov. A k tomu plus este 20-30% kvoli spomaleniu videoramky. Pedesiatina trva iba cca 70000 taktov, takze bez nejakeho "spinaveho" triku nie je sanca

Nahoru

Busy

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 07.08.2013, 07:06

Óm Nejvyšší

Registrován: 22.05.2013, 21:14
Příspěvky: 3674
Bydliště: Bratislava
Has thanked: 373 times
Been thanked: 798 times

Btw ked uz o tom pisem, tak s DMA sa to v pohode stiha

[youtube]http://www.youtube.com/watch?v=GEkQTmYMrcA[/youtube]

Nahoru

Lanex

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 07.08.2013, 14:49

Radil

Registrován: 12.05.2013, 20:32
Příspěvky: 457
Bydliště: Kladno
Has thanked: 46 times
Been thanked: 118 times

podle mě se vám nepovede udělat rychlejší scroll na 128K, druhá VRAM v tomhle případě nemá žadný rychlostní vliv. Maximálně se tím vyhnete protnutí paprsku se zrovna přenášenými daty. Rychleji je však nepřenesete.

Pavero: všiml jsem si že jsi svůj scroll napsal od adresy (ORG) 29000. To je ještě v pomalé části paměti, nějaký další čas navíc získáš přesunem kódu do rychlejší paměti (ORG 32768 a více). Paprsek tě ale i v tomhle případě předběhne ;-)

_________________
>>eLeMeNt, MB03+, Amiga 1200, ZX Spectrum 128 +2A, ZX Spectrum+, Didaktik Gama, LnxSpectrum, LnxTracker, LnxAmigaImageConvertor, https://www.ilnx.cz <<

Nahoru

_dworkin

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 07.08.2013, 17:08

Pan Štábní

Registrován: 23.06.2013, 23:49
Příspěvky: 1119
Has thanked: 100 times
Been thanked: 161 times

Lanex píše:

Ja to chapu tak, ze mu nejde o rychlost ale "plynulost", aby to netrhalo oci. Takze pokud 128 ma prepinatelnou RAMku, tak to neni vyzva. Bude to mit proste 25 fps.

_________________
Z80 Forth compiler (ZX Spectrum 48kb): https://codeberg.org/DW0RKiN/M4_FORTH

Nahoru

pavero

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 07.08.2013, 20:50

Kecálek

Registrován: 18.05.2013, 11:46
Příspěvky: 183
Bydliště: Ústí nad Orlicí
Has thanked: 11 times
Been thanked: 63 times

Tak jsem vzal ještě _dworkinovo řešení a dle jeho rady ho rozdělil na třetiny. Dal jsem paprsku ještě větší náskok (po prvním zavolání HALT). Výsledek je podstatně lepší, byť nyní k problikům dochází hlavně ve druhé třetině obrazu (rambo24_2.sna). Nejvíce šetrná očím je stále tedy ta úplně první komplikovaná a pomalejší varianta s podpůrnými funkcemi DOWNHL a UPHL, kde je drobný rozpad pouze na úrovni cca 17. atributového řádku (rambo24.sna).

Kód:

      org 35000
START2      ld hl,40000      
      ld de,16384
      ld bc,6912
      ldir

      im 1
      ei

      ld a,32         ;pocet opakovani
START      push af

      halt         ;pockani na zahajeni vykreslovani obrazu
      ld a, 7
                call WAIT      ;cekani na posun paprsku
            
      call MOVELEFT      ;posun obrazu o 1 atribut doleva
      
                ld a,150
      call wait
           
      pop af
      dec a
      jr nz,START
      jr START2
MOVELEFT

      ld a,3 ;tretiny   

      ld hl, 22529
      ld de, 22528   
      exx
      ld   hl,16385
      ld   de,16384

mlALL push af

      ld a,8  
pixels
      ldi   ; 16 taktu:2byty (de++) = (hl++), ignore bc--
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi   ; 8x

      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi   ; 16x
      
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi   ; 24x

      ldi
      ldi
      ldi
      ldi
      ldi
      ldi
      ldi   ; 31x


      inc l
      inc e     ; preskoc posledni sloupec
      
      jp  nz , pixels
   
      inc d
      dec a
      jp nz, pixels

      exx 

atributy 
      ld   bc,31
      ldir      
      inc l
      inc e     ; preskoc posledni sloupec      
      jp  nz , atributy      
      inc d


      pop af   
      exx   
      dec a         
      jp nz, mlAll     
      ret      


;spomalovaci smycka
WAIT      ld b,255
WAIT_INNER   djnz WAIT_INNER
      dec a
      jr nz,WAIT
         ret   

Přílohy:

rambo24.sna [48.03 KiB]
203 krát

rambo24_2.sna [48.03 KiB]
213 krát

_________________
https://zx-spectrum.cz
https://maps.speccy.cz
https://www.zx-spectrum.cz/collection/
https://cs.speccy.cz
https://spectrumcomputing.co.uk/

Naposledy upravil pavero dne 07.08.2013, 21:27, celkově upraveno 1

Nahoru

pavero

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 07.08.2013, 21:08

Kecálek

Registrován: 18.05.2013, 11:46
Příspěvky: 183
Bydliště: Ústí nad Orlicí
Has thanked: 11 times
Been thanked: 63 times

Celkem by mě zajímalo, jak je řešen scroll ve hře Lost Caves, který je naprosto plynulý. Není to sice celoobrazovkový scroll, ale hrací plocha je přes dvě třetiny obrazu. Původně jsem si myslel, že je to 128K hra, ale bez problému jde spustit i na 48K verzi.

Mé znalosti assembleru jsou chabé na to, abych to dokázal disassemblovat, takže mi to zatím hlava nebere

.

http://www.worldofspectrum.org/infoseek ... id=0002936

_________________
https://zx-spectrum.cz
https://maps.speccy.cz
https://www.zx-spectrum.cz/collection/
https://cs.speccy.cz
https://spectrumcomputing.co.uk/

Nahoru

Lanex

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 07.08.2013, 21:55

Radil

Registrován: 12.05.2013, 20:32
Příspěvky: 457
Bydliště: Kladno
Has thanked: 46 times
Been thanked: 118 times

pavero píše:

Toť otázka, kolik taktů vlastně zabere prohození VRAMek u 128k? O verzi 128K vím prd, ale chápal jsem to tak, že procesoru sice zabere stejné množství času její naplnění, ale to si mohu připravit na pozadí a pak následné prohození je už podstatně rychlejší a stihne se do 1/50s. Nebo je to celé jinak?

Přesně jak píšeš. Přehození VideoRAM ve ZX 128k stojí 3 instrukce (ld bc,$7ffd / ld a,8 / out (c),a), tohle sebere 28 taktů. Nemusíš na začátku čekat na zpoždění paprsku. Počkáš na přerušení (HALT), hned přehodíš videoram a ve skryté videoram začneš aktualizovat obsah. Až to dokončíš, dáš zase HALT, zase prohodíš videoram (ld a,0) a budeš to celé opakovat. Tohle ti zaručí že uprostřed obrazovky nikdy nevznikne defekt.

Koukal jsem - a Lost caves používá obě videoram v ZX 128k, a přepíná mezi nimi. 48K verzi jsem neprohlížel.

_________________
>>eLeMeNt, MB03+, Amiga 1200, ZX Spectrum 128 +2A, ZX Spectrum+, Didaktik Gama, LnxSpectrum, LnxTracker, LnxAmigaImageConvertor, https://www.ilnx.cz <<

Nahoru

Busy

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 07.08.2013, 22:58

Óm Nejvyšší

Registrován: 22.05.2013, 21:14
Příspěvky: 3674
Bydliště: Bratislava
Has thanked: 373 times
Been thanked: 798 times

Lanex píše:

Presne to som napisal zopar prispevkov vyssie :bulb:

_dworkin píše:

Ja to chapu tak, ze mu nejde o rychlost ale "plynulost", aby to netrhalo oci. Takze pokud 128 ma prepinatelnou RAMku, tak to neni vyzva. Bude to mit proste 25 fps.

A 25fps zial trha oci riadne :bang:

Nahoru

_dworkin

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 08.08.2013, 00:26

Pan Štábní

Registrován: 23.06.2013, 23:49
Příspěvky: 1119
Has thanked: 100 times
Been thanked: 161 times

Busy píše:

Btw. jedno LDI trva 16 taktov, takze posun celej obrazovky aj s atributami + nejaka rezia okolo by si vyziadali vyse 110000 taktov. A k tomu plus este 20-30% kvoli spomaleniu videoramky. Pedesiatina trva iba cca 70000 taktov, takze bez nejakeho "spinaveho" triku nie je sanca

31*8*24*16=5952*16=95232

Pokud zacne hned za paprskem tak ma teda 70k taktu nez paprsek bude na prvnim mikroradku a to uz muze byt ve treti tretine a nez probehne paprsek dve tak bude zase dal ne? Jen potrebuje zpocatku bezet za paprskem taky pekne po mikroradcich.

Kód:

; VSTUP:    ixl = segment radku
; VYSTUP:   a = b = ixh = l = 0
;       e = $ff
; cca 45858 cyklu na tretinu
SCROLL_PO_RADCICH:
   xor   a
   ld   ixh,8      ; 11:3 pocitadlo radku v tretine
SCROLL_RADEK:  
   ld   d,ixl      ; 8:2 
   ld   h,d      ; 4:1 segment na zacatek   
SCROLL_SELF_MODIFYING:
   ld   bc,$08ff   ; 10:3 $08ff pokud kopirujeme obraz, $01ff pokud kopirujeme atributy
SCROLL_MICROLINE:

   ld   e,a      ; 4:1
   ld   l,a      ; 4:1
   inc   l      ; 4:1

   ldi   ; 16 taktu:2byty (de++) = (hl++), ignore bc--
   ldi
   ldi
   ldi
   ldi
   ldi
   ldi
   ldi   ; 8x

   ldi
   ldi
   ldi
   ldi
   ldi
   ldi
   ldi
   ldi   ; 16x
     
   ldi
   ldi
   ldi
   ldi
   ldi
   ldi
   ldi
   ldi   ; 24x

   ldi
   ldi
   ldi
   ldi
   ldi
   ldi
   ldi   ; 31x

   inc   d         ; 4:1 o mikroradek nize
   ld   h,d         ; 4:1 protoze u posledniho radku tretiny pretika v kazdem mikroradku a jindy ne, ale vzhledem k tomu ze ma byt shodny s "d"...
      
   djnz   SCROLL_MICROLINE   ; 13/8:2
      
   ld   a,l         ; uz bylo zvyseno o 32
            
   dec   ixh         ; 8:2 snizime pocitadlo radku v tretine
   jr   nz,SCROLL_RADEK      ; 12/7:2
      
   ret

vola se to:

Kód:

   ; 1. tretina 
   ld   a,8
   ld   (SCROLL_SELF_MODIFYING+2),a
        ld   ixl,$40
   call   SCROLL_PO_RADCICH
   ; 1. tretina atributy
   inc   a
   ld   (SCROLL_SELF_MODIFYING+2),a
   ld   ixl,$58
   call   SCROLL_PO_RADCICH

_________________
Z80 Forth compiler (ZX Spectrum 48kb): https://codeberg.org/DW0RKiN/M4_FORTH

Nahoru

Busy

Předmět příspěvku: Re: Celoobrazovkový scroll na 48K

Napsal: 08.08.2013, 06:00

Óm Nejvyšší

Registrován: 22.05.2013, 21:14
Příspěvky: 3674
Bydliště: Bratislava
Has thanked: 373 times
Been thanked: 798 times

_dworkin píše:

31*8*24*16=5952*16=95232

To je ale bez atributov. A nezabudaj este pripocitat 20 az 30% casu naviac kvoli spomaleniu videoramky.

Pokial sa po preruseni pocka na zobrazenie prveho mikroriadku a scroll sa zacne az potom, je mozne sa vyhnut konfliktu s lucom, avsak takymto sposobom sa neda dosiahnut 50 fps. Takze scrollovany obraz sice bude celistvy, nerozbity, avsak scroll nebude plynuly - pobezi maximalne na 25 fps.

Nahoru

Stránka 1 z 4

[ Příspěvků: 49 ]

Přejít na stránku 1, 2, 3, 4 Další

Obsah fóra » ZX Spectrum, Sinclair a kompatibilní » ZX Spectrum - programování a vývoj software

Všechny časy jsou v UTC + 1 hodina [ Letní čas ]

Kdo je online

Uživatelé procházející toto fórum: Žádní registrovaní uživatelé a 11 návštevníků

Nemůžete zakládat nová témata v tomto fóru
Nemůžete odpovídat v tomto fóru
Nemůžete upravovat své příspěvky v tomto fóru
Nemůžete mazat své příspěvky v tomto fóru
Nemůžete přikládat soubory v tomto fóru

Přejít na: