OldComp.cz

    ld   HL, 0xffff     ; 3:10
    push HL             ; 1:11
    pop  AF             ; 1:10   AF = 0xffff

Hex    8     4   2    1    8    4    2    1
Bit    7    6    5    4    3    2    1    0
Flag   S    Z   F5    H   F3  P/V    N    C

Org 0x8000

xor a ;--> 0x0044
inc a ;--> 0x0100
inc a ;--> 0x0200
inc a ;--> 0x0300

xor a ;--> 0x0044
inc a ;--> 0x0100
ld a,0x12 ;--> 0x1200  tohle by melo resit zbytek hodnot 0x??44

xor a ;--> 0x0044
dec a ;--> 0xFFBA
dec a ;--> 0xFEAA
dec a ;--> 0xFDAA

xor a ;--> 0x0044
cpl   ;--> 0xFF7E
inc a ;--> 0x0050 !!!
inc a ;--> 0x0100 lepsi je jen inc a po xor a

xor a ;--> 0x0044
cpl   ;--> 0xFF7E
dec a ;--> 0xFEAA to same co 2x dec a
dec a ;--> 0xFDAA to same co 3x dec a

xor a ;--> 0x0044
inc a ;--> 0x0100
cpl   ;--> 0xFE3A

xor a ;--> 0x0044
dec a ;--> 0xFFBA
cpl   ;--> 0x0092 !!!

xor a ;--> 0x0044
inc a ;--> 0x0100
ld a,0x00 ;--> 0x0000 !!!!

xor a ;--> 0x0044
inc a ;--> 0x0100
rra ;--> 0x0001 !!!!

ret

xor a ;--> 0x0044
ccf   ;--> 0x0045 !!!
inc a ;--> 0x0101
inc a ;--> 0x0201

xor a ;--> 0x0044
inc a ;--> 0x0100
inc a ;--> 0x0200
ccf   ;--> 0x0201

xor a ;--> 0x0044
inc a ;--> 0x0100
ccf   ;--> 0x0101
inc a ;--> 0x0201

xor a ;--> 0x0044
inc a ;--> 0x0100
ccf   ;--> 0x0101
dec a ;--> 0x0043 !!!

xor a ;--> 0x0044
ccf   ;--> 0x0045
dec a ;--> 0xFFBB
dec a ;--> 0xFEAB

xor a ;--> 0x0044
dec a ;--> 0xFFBA
ccf   ;--> 0xFFA9
inc a ;--> 0x0051 !!!

xor a ;--> 0x0044
dec a ;--> 0xFFBA
ccf   ;--> 0xFFA9
dec a ;--> 0xFEAB

xor a ;--> 0x0044
dec a ;--> 0xFFBA
dec a ;--> 0xFEAA
ccf   ;--> 0xFEA9

xor a ;--> 0x0044
cpl   ;--> 0xFF7E
ccf   ;--> 0xFF6D
inc a ;--> 0x0050 !!!

xor a ;--> 0x0044
cpl   ;--> 0xFF7E
ccf   ;--> 0xFF6D
dec a ;--> 0xFFAB

xor a ;--> 0x0044
inc a ;--> 0x0100
rra   ;--> 0x0001 !!!
ccf   ;--> 0x0010 !!!

0x0144 == xor a / ccf / rla
0x0110 == xor a / inc a / and a
0x8001 == xor a / inc a / rrca
0x8044 == xor a / ccf / cca

0x998f == xor a / cpl / daa
0x6025 == xor a / ccf / daa

    org 0x8000
    ld    L, 0x1A       ; 2:7       init   Upper screen
    call 0x1605         ; 3:17      init   Open channel
 
_use_e equ 1
_use_d equ 1
 
 if _use_e
    ld E,max
e_loop
    ld H,high opcode
    ld L, E
    ld A,[HL]
    ld [_first], A
 endif
 
 if _use_d
    ld D,max
d_loop
    ld H,high opcode
    ld L, D
    ld A,[HL]
    ld [_second], A
  endif
 
    ld C,max
c_loop
    ld H,high opcode
    ld L, C
    ld A,[HL]
    ld [_third], A
   
    ld B,max
b_loop
    ld H,high opcode
    ld L, B
    ld A,[HL]
    ld [_fourth], A
   
self_mod_code:
    xor A
_first:
    db 0x00
_second:
    db 0x00
_third:
    db 0x00
_fourth:
    db 0x00

    push af
    pop  hl
   
    call my_print

    djnz b_loop
    dec C
    jr nz, c_loop
  if _use_d
    dec D
    jr nz, d_loop
  endif
  if _use_e
    dec E
    jp nz, e_loop
  endif
    ret


    ; hl = af
my_print:
    push de
    push bc
 
    push DE             ; 1:11      dup   ( a -- a a )
    ld    D, H          ; 1:4       dup
    ld    E, L          ; 1:4       dup
    call PRT_HEX_U16    ; 3:17      hex u.   ( u -- )
    ex   DE, HL         ; 1:4       hex u.
    pop  DE             ; 1:10      hex u.

    ld    A, 0x0D       ; 2:7       cr   Pollutes: AF, AF', DE', BC'
    rst   0x10          ; 1:11      cr   putchar(reg A) with ZX 48K ROM

    ex   DE, HL         ; 1:4       DE --> HL

 if _use_e
    ld    A, L
    add   A, A
    add   A, A
    add   A, A
    add   A, low opcode_text
    ld    E, A
    ld    D, high opcode_text   
    ld   BC, 0x0008     ; 3:10
    call 0x203C         ; 3:17   Print our string with ZX 48K ROM
 endif
 
 if _use_d
    ld    A, H
    add   A, A
    add   A, A
    add   A, A
    add   A, low opcode_text
    ld    E, A
    ld    D, high opcode_text   
    ld   BC, 0x0008     ; 3:10
    call 0x203C         ; 3:17   Print our string with ZX 48K ROM
  endif
    pop  BC
    push Bc
    ld    A, C
    add   A, A
    add   A, A
    add   A, A
    add   A, low opcode_text
    ld    E, A
    ld    D, high opcode_text   
    ld   BC, 0x0008     ; 3:10
    call 0x203C         ; 3:17   Print our string with ZX 48K ROM

    pop  BC
    push BC
    ld    A, B
    add   A, A
    add   A, A
    add   A, A
    add   A, low opcode_text
    ld    E, A
    ld    D, high opcode_text   
    ld   BC, 0x0007     ; 3:10
    call 0x203C         ; 3:17   Print our string with ZX 48K ROM
   
    ld    A, 0x0D       ; 2:7       cr   Pollutes: AF, AF', DE', BC'
    rst   0x10          ; 1:11      cr   putchar(reg A) with ZX 48K ROM

    pop  BC
    pop  de
    ret
   
;#------------------------------------------------------------------------------
;#   Input: 16-bit unsigned number in HL
;#   Output: Print Hex HL
;# Pollutes: A
PRT_HEX_U16:            ;           prt_hex_u16
    ld    A, H          ;  1:4      prt_hex_u16
    call PRT_HEX_A      ;  3:17     prt_hex_u16
    ld    A, L          ;  1:4      prt_hex_u16
    ; fall to prt_hex_a
;#------------------------------------------------------------------------------
;#    Input: A
;#   Output: 00 .. FF
;# Pollutes: A
PRT_HEX_A:              ;           prt_hex_a
    push AF             ; 1:11      prt_hex_a
    rra                 ; 1:4       prt_hex_a
    rra                 ; 1:4       prt_hex_a
    rra                 ; 1:4       prt_hex_a
    rra                 ; 1:4       prt_hex_a
    call PRT_HEX_NIBBLE ; 3:17      prt_hex_a
    pop  AF             ; 1:10      prt_hex_a
    ; fall to prt_hex_nibble
;#------------------------------------------------------------------------------
;#    Input: A = number, DE = adr
;#   Output: (A & $0F) => '0'..'9','A'..'F'
;# Pollutes: AF, AF',BC',DE'
PRT_HEX_NIBBLE:         ;           prt_hex_nibble
    or      $F0         ; 2:7       prt_hex_nibble   reset H flag
    daa                 ; 1:4       prt_hex_nibble   $F0..$F9 + $60 => $50..$59; $FA..$FF + $66 => $60..$65
    add   A, $A0        ; 2:7       prt_hex_nibble   $F0..$F9, $100..$105
    adc   A, $40        ; 2:7       prt_hex_nibble   $30..$39, $41..$46   = '0'..'9', 'A'..'F'
    rst   0x10          ; 1:11      prt_hex_nibble   putchar(reg A) with ZX 48K ROM
    ret                 ; 1:10
; seconds: 0           ;[31:175]

DEFS    (($ + 256 - 1) / (256)) * (256) - $
opcode:
db 0x00 ; zero       ; --------
db 0x00 ; nop        ; --------
db 0x07 ; rlca       ; --503-0C
db 0x0F ; rrca       ; --503-0C
db 0x17 ; rla        ; --503-0C
db 0x1F ; rra        ; --503-0C
db 0x27 ; daa        ; SZ5H3P-C
db 0x2F ; cpl        ; --513-1-
db 0x3F ; ccf        ; --5H3-0C
db 0x3C ; inc a      ; SZ5H3PN-
db 0x3D ; dec a      ; SZ5H3PN-
db 0x87 ; add a,a    ; SZ5H3PNC
db 0x8F ; adc a,a    ; SZ5H3PNC
db 0xA7 ; and a      ; SZ513P00
db 0xB7 ; or a       ; SZ503P00

max equ $-opcode-1

opcode_text:
db "zero   /"    ; --------
db "nop    /"    ; --------
db "rlca   /"    ; --503-0C
db "rrca   /"    ; --503-0C
db "rla    /"    ; --503-0C
db "rra    /"    ; --503-0C
db "daa    /"    ; SZ5H3P-C
db "cpl    /"    ; --513-1-
db "ccf    /"    ; --5H3-0C
db "inc a  /"    ; SZ5H3PN-
db "dec a  /"    ; SZ5H3PN-
db "add a,a/"    ; SZ5H3PNC
db "adc a,a/"    ; SZ5H3PNC
db "and a  /"    ; SZ513P00
db "or a   /"    ; SZ503P00

  if 1
; The channels are used as follows by the Spectrum ROM:
;
; 3 (P) is used by LPRINT and LLIST.
; 2 (S) is used by PRINT and LIST.
; 1 (K) is used by the INPUT command.
; 0 (K) is used by the BASIC line editor; it is always reset to K after each RUN, so redirecting it has no effect.
; -1 (R) inserts the characters where the system variable K-CUR is pointing in memory - typically either in the edit area (E-LINE) when pulling down a BASIC line for editing, or in the internal workspace (WORKSP) when evaluating STR$.
; -2 (S) is used by LOAD to print file information to the screen, and when scrolling the screen.
; -3 (K) is used by SAVE for the "press any key" prompt, and for the "scroll?" prompt when the screen is full.
 
    ld    A, 0x03       ; 2:7       init   Upper screen
    call 0x1601         ; 3:17      init   Open channel
  else
    ld    L, 0x1A       ; 2:7       init   Upper screen  0x1A = 2*stream+22
    call 0x1605         ; 3:17      init   Open channel
 endif

    ld    L, 0x1A       ; 2:7       init   Upper screen  0x1A = 2*stream+22
    call 0x1605         ; 3:17      init   Open channel

db 0x00 ; zero       ; --------
db 0x00 ; nop        ; --------
db 0x07 ; rlca       ; --503-0C
db 0x0F ; rrca       ; --503-0C
db 0x17 ; rla        ; --503-0C
db 0x1F ; rra        ; --503-0C
db 0x27 ; daa        ; SZ5H3P-C
db 0x2F ; cpl        ; --513-1-
db 0x3F ; ccf        ; --5H3-0C
db 0x3C ; inc a      ; SZ5H3PN-
db 0x3D ; dec a      ; SZ5H3PN-
db 0x87 ; add a,a    ; SZ5H3PNC
db 0x8F ; adc a,a    ; SZ5H3PNC
db 0xA7 ; and a      ; SZ513P00
db 0xB7 ; or a       ; SZ503P00

fuse --debugger-command 'br 0x8000' flag_old.tap
fuse --debugger-command='br 0x8000' flag_old.tap
fuse --debugger-command "br 0x8000" flag_old.tap
fuse --debugger-command="br 0x8000" flag_old.tap

    org 0x8000
   
  if 0
; The channels are used as follows by the Spectrum ROM:
;
; 3 (P) is used by LPRINT and LLIST.
; 2 (S) is used by PRINT and LIST.
; 1 (K) is used by the INPUT command.
; 0 (K) is used by the BASIC line editor; it is always reset to K after each RUN, so redirecting it has no effect.
; -1 (R) inserts the characters where the system variable K-CUR is pointing in memory - typically either in the edit area (E-LINE) when pulling down a BASIC line for editing, or in the internal workspace (WORKSP) when evaluating STR$.
; -2 (S) is used by LOAD to print file information to the screen, and when scrolling the screen.
; -3 (K) is used by SAVE for the "press any key" prompt, and for the "scroll?" prompt when the screen is full.
 
    ld    A, 0x03       ; 2:7       init   Upper screen
    call 0x1601         ; 3:17      init   Open channel
  else
    ld    L, 0x1A       ; 2:7       init   Upper screen  0x1A = 2*stream+22
    call 0x1605         ; 3:17      init   Open channel
 endif
 
 table equ 1
 if 0
look_for equ 0xBC
 endif
    ld C,0
c_loop
    ld A,C
    ld [_first], A
   
    ld B,0
b_loop
    ld A,B
    ld [_second], A
   
self_mod_code:
_first equ $+1
    ld A, 0x00
_second equ $+1
    add A, 0x00

    push af
    pop  hl
   
  if table
    call make_table
  else
    call my_print
  endif
 
    djnz b_loop
    dec C
    jr nz, c_loop
 
 
  if table
    ld HL, found
loop:
    ld A,[HL]
    or A
   
    jr z, no_print
   
    ld   A, L
    call PRT_HEX_A
    ld    A, 0x0D       ; 2:7       cr   Pollutes: AF, AF', DE', BC'
    rst   0x10          ; 1:11      cr   putchar(reg A) with ZX 48K ROM
no_print:
    inc L
    jr nz, loop
  endif
    ret

make_table:
    ; HL = AF
    ld   H, high found
    ld [HL],1
    ret

   
    ; hl = af
my_print: 
   
  ifdef look_for
    ld    A, look_for
    cp    L
    ret  nz   
  endif
   
    push BC
    push DE             ; 1:11      dup   ( a -- a a )
    ld    D, H          ; 1:4       dup
    ld    E, L          ; 1:4       dup
    call PRT_HEX_U16    ; 3:17      hex u.   ( u -- )
    ex   DE, HL         ; 1:4       hex u.
    pop  DE             ; 1:10      hex u.

    ld    A, 0x0D       ; 2:7       cr   Pollutes: AF, AF', DE', BC'
    rst   0x10          ; 1:11      cr   putchar(reg A) with ZX 48K ROM

    ld    H, B
    ld    L, C

    ld   DE,_ld_a_n   
    ld   BC, size_ld_a_n; 3:10
    call 0x203C         ; 3:17   Print our string with ZX 48K ROM
    ld    A, L
    call PRT_HEX_A
   
    ld   DE,_add_a_n
    ld   BC, size_add_a_n; 3:10
    call 0x203C         ; 3:17   Print our string with ZX 48K ROM
    ld    A, H
    call PRT_HEX_A
   
    ld    A, 0x0D       ; 2:7       cr   Pollutes: AF, AF', DE', BC'
    rst   0x10          ; 1:11      cr   putchar(reg A) with ZX 48K ROM

    pop  BC
    ret
   
;#------------------------------------------------------------------------------
;#   Input: 16-bit unsigned number in HL
;#   Output: Print Hex HL
;# Pollutes: A
PRT_HEX_U16:            ;           prt_hex_u16
    ld    A, H          ;  1:4      prt_hex_u16
    call PRT_HEX_A      ;  3:17     prt_hex_u16
    ld    A, L          ;  1:4      prt_hex_u16
    ; fall to prt_hex_a
;#------------------------------------------------------------------------------
;#    Input: A
;#   Output: 00 .. FF
;# Pollutes: A
PRT_HEX_A:              ;           prt_hex_a
    push AF             ; 1:11      prt_hex_a
    rra                 ; 1:4       prt_hex_a
    rra                 ; 1:4       prt_hex_a
    rra                 ; 1:4       prt_hex_a
    rra                 ; 1:4       prt_hex_a
    call PRT_HEX_NIBBLE ; 3:17      prt_hex_a
    pop  AF             ; 1:10      prt_hex_a
    ; fall to prt_hex_nibble
;#------------------------------------------------------------------------------
;#    Input: A = number, DE = adr
;#   Output: (A & $0F) => '0'..'9','A'..'F'
;# Pollutes: AF, AF',BC',DE'
PRT_HEX_NIBBLE:         ;           prt_hex_nibble
    or      $F0         ; 2:7       prt_hex_nibble   reset H flag
    daa                 ; 1:4       prt_hex_nibble   $F0..$F9 + $60 => $50..$59; $FA..$FF + $66 => $60..$65
    add   A, $A0        ; 2:7       prt_hex_nibble   $F0..$F9, $100..$105
    adc   A, $40        ; 2:7       prt_hex_nibble   $30..$39, $41..$46   = '0'..'9', 'A'..'F'
    rst   0x10          ; 1:11      prt_hex_nibble   putchar(reg A) with ZX 48K ROM
    ret                 ; 1:10
; seconds: 0           ;[31:175]

_ld_a_n:
db "ld a,$"
size_ld_a_n equ $-_ld_a_n
_add_a_n
db "/add a,$"
size_add_a_n equ $-_add_a_n


DEFS    (($ + 256 - 1) / (256)) * (256) - $

found:

ds 256

    org 0x8000
   
  if 0
; The channels are used as follows by the Spectrum ROM:
;
; 3 (P) is used by LPRINT and LLIST.
; 2 (S) is used by PRINT and LIST.
; 1 (K) is used by the INPUT command.
; 0 (K) is used by the BASIC line editor; it is always reset to K after each RUN, so redirecting it has no effect.
; -1 (R) inserts the characters where the system variable K-CUR is pointing in memory - typically either in the edit area (E-LINE) when pulling down a BASIC line for editing, or in the internal workspace (WORKSP) when evaluating STR$.
; -2 (S) is used by LOAD to print file information to the screen, and when scrolling the screen.
; -3 (K) is used by SAVE for the "press any key" prompt, and for the "scroll?" prompt when the screen is full.
 
    ld    A, 0x03       ; 2:7       init   Upper screen
    call 0x1601         ; 3:17      init   Open channel
  else
    ld    L, 0x1A       ; 2:7       init   Upper screen  0x1A = 2*stream+22
    call 0x1605         ; 3:17      init   Open channel
 endif
 
 table equ 1
 if 0
look_for equ 0xBC
 endif
    ld C,0
c_loop
    ld A,C
    ld [_first], A
   
    ld B,0
b_loop
    ld A,B
    ld [_second], A
   
self_mod_code:
_first equ $+1
    ld A, 0x00
_second equ $+1
    sub 0x00

    push af
    pop  hl
   
  if table
    call make_table
  else
    call my_print
  endif
 
    djnz b_loop
    dec C
    jr nz, c_loop
 
 
  if table
    ld HL, found
loop:
    ld A,[HL]
    or A
   
    jr z, no_print
   
    ld   A, L
    call PRT_HEX_A
    ld    A, 0x0D       ; 2:7       cr   Pollutes: AF, AF', DE', BC'
    rst   0x10          ; 1:11      cr   putchar(reg A) with ZX 48K ROM
no_print:
    inc L
    jr nz, loop
  endif
    ret

make_table:
    ; HL = AF
    ld   H, high found
    ld [HL],1
    ret

   
    ; hl = af
my_print: 
   
  ifdef look_for
    ld    A, look_for
    cp    L
    ret  nz   
  endif
   
    push BC
    push DE             ; 1:11      dup   ( a -- a a )
    ld    D, H          ; 1:4       dup
    ld    E, L          ; 1:4       dup
    call PRT_HEX_U16    ; 3:17      hex u.   ( u -- )
    ex   DE, HL         ; 1:4       hex u.
    pop  DE             ; 1:10      hex u.

    ld    A, 0x0D       ; 2:7       cr   Pollutes: AF, AF', DE', BC'
    rst   0x10          ; 1:11      cr   putchar(reg A) with ZX 48K ROM

    ld    H, B
    ld    L, C

    ld   DE,_ld_a_n   
    ld   BC, size_ld_a_n; 3:10
    call 0x203C         ; 3:17   Print our string with ZX 48K ROM
    ld    A, L
    call PRT_HEX_A
   
    ld   DE,_sub_n
    ld   BC, size_sub_n; 3:10
    call 0x203C         ; 3:17   Print our string with ZX 48K ROM
    ld    A, H
    call PRT_HEX_A
   
    ld    A, 0x0D       ; 2:7       cr   Pollutes: AF, AF', DE', BC'
    rst   0x10          ; 1:11      cr   putchar(reg A) with ZX 48K ROM

    pop  BC
    ret
   
;#------------------------------------------------------------------------------
;#   Input: 16-bit unsigned number in HL
;#   Output: Print Hex HL
;# Pollutes: A
PRT_HEX_U16:            ;           prt_hex_u16
    ld    A, H          ;  1:4      prt_hex_u16
    call PRT_HEX_A      ;  3:17     prt_hex_u16
    ld    A, L          ;  1:4      prt_hex_u16
    ; fall to prt_hex_a
;#------------------------------------------------------------------------------
;#    Input: A
;#   Output: 00 .. FF
;# Pollutes: A
PRT_HEX_A:              ;           prt_hex_a
    push AF             ; 1:11      prt_hex_a
    rra                 ; 1:4       prt_hex_a
    rra                 ; 1:4       prt_hex_a
    rra                 ; 1:4       prt_hex_a
    rra                 ; 1:4       prt_hex_a
    call PRT_HEX_NIBBLE ; 3:17      prt_hex_a
    pop  AF             ; 1:10      prt_hex_a
    ; fall to prt_hex_nibble
;#------------------------------------------------------------------------------
;#    Input: A = number, DE = adr
;#   Output: (A & $0F) => '0'..'9','A'..'F'
;# Pollutes: AF, AF',BC',DE'
PRT_HEX_NIBBLE:         ;           prt_hex_nibble
    or      $F0         ; 2:7       prt_hex_nibble   reset H flag
    daa                 ; 1:4       prt_hex_nibble   $F0..$F9 + $60 => $50..$59; $FA..$FF + $66 => $60..$65
    add   A, $A0        ; 2:7       prt_hex_nibble   $F0..$F9, $100..$105
    adc   A, $40        ; 2:7       prt_hex_nibble   $30..$39, $41..$46   = '0'..'9', 'A'..'F'
    rst   0x10          ; 1:11      prt_hex_nibble   putchar(reg A) with ZX 48K ROM
    ret                 ; 1:10
; seconds: 0           ;[31:175]

_ld_a_n:
db "ld a,$"
size_ld_a_n equ $-_ld_a_n
_sub_n
db "/sub $"
size_sub_n equ $-_sub_n


DEFS    (($ + 256 - 1) / (256)) * (256) - $

found:

ds 256

    ld    A, ' '        ; 2:7       space   Pollutes: AF, AF', DE', BC'