Tak zkusme udělat nějaký Z80 benchmark. Je zde volnost v tom, jak rozhodnout, co je typicky používaný
program. Může to být třeba nějaká hra, která zobrazuje grafické ikony (bitmapy) velikosti 32x32
pixelů. Budeme předpokládat, že kopírování těch bitmap zabere většinu času, a že tedy benchmark bude
napodobovat jen to, a ne nějakou herní logiku. Ještě předpokládáme, že 8 pixelů je uloženo v jednom
byte, že x pozice na obrazovce bude vždy násobek osmi, a že řádka obrazovky má 320 pixelů. Také
předpokládáme, že v grafické paměti jsou pixely uloženy za sebou, odshora dolů, zleva doprava, jako
jedna bitová rovina (kopírování barevného obrázku je potom jako kopírování několika černobílých po
sobě). Všechny tyto předpoklady platí pro Sharp MZ-800.
Funkcionalita rutiny je jako memcpy (kopírování paměti), ale s tím rozdílem, že kopírujeme jeden
souvislý blok do několika nesouvislých.
Program uložíme od adresy 2000h, data bitmapy simulujeme na adrese 2080h, a VRAM je simulovaná na
adrese 2100h. Nezapisujeme tedy skutečně do VRAM, jen do RAM, díky tomu ten benchmark testuje rychlost
samotného CPU, bez ohledu na rychlost VRAM.
Pro spouštění na jiné platformě bude možná potřeba změnit všechny tři adresy, tak aby všechny tři
ležely v oblasti RAM.
Rutina potřebuje celkem asi 183 600 000 cyklů procesoru. To odpovídá časům:
45.9 sec @ 4 Mhz
51.7 sec @ 3.55 Mhz (Sharp MZ-800)
Pro Sharp MZ platí, že ho nic nebrzdí, čas běhu se tedy dá přímo odvodit od kmitočtu hodin procesoru.
Kód v asembleru:
Kód: ; Z80 graphics benchmark
; version 1
; Simulates copying of 32x32 px bitmap from memory to vram
; Repeated 65536 times
; Expected time is 45.9 sec for a Z80 @ 4 MHz
; Change starting address so that it points to a RAM area on your platform
.org 2000h
bitmap .equ 2080h
vram .equ 2100h
di
ld bc,0
benchloop:
push bc
ld (restore+1),sp
ld sp,bitmap
ld hl,vram
ld bc,37
ld a,16
copyrow:
pop de
ld (hl),e
inc hl
ld (hl),d
inc hl
pop de
ld (hl),e
inc hl
ld (hl),d
add hl,bc
pop de
ld (hl),e
inc hl
ld (hl),d
inc hl
pop de
ld (hl),e
inc hl
ld (hl),d
add hl,bc
dec a
jp nz,copyrow
restore:
ld sp,0
pop bc
dec bc
ld a,b
or c
jr nz,benchloop
ei
ret
Hex kódy po přeložení (pro naťukání pomocí monitoru):
Kód: F3 01 00 00 C5 ED 73 2D 20 31 80 20 21 00 21 01
25 00 3E 10 D1 73 23 72 23 D1 73 23 72 09 D1 73
23 72 23 D1 73 23 72 09 3D C2 14 20 31 00 00 C1
0B 78 B1 20 CF FB C9
|
Dokážu si představit tato využití benchmarku v konkrétním programovacím jazyce (BASIC, C, cokolivjiného...):
